REBOL[Title: "Thumbnail Maker"
	Author: "Tim Wylie"
	Date: "21-Dec-2005"]

view layout[
	backdrop 239.235.222
	origin 4	space 4x4	across
	images: text-list 150 data load %.
	at 160x4 text "New Width:" at 240x4 w: field 40 
	at 160x30 text "New Height:" at 240x30 h: field 40
	at 160x56 button "Create Thumb"[
		foreach img_name images/picked [
			if error? try [
				img: load-thru/binary to-file img_name
				;img: to-image bin
				size: img/size
				new_size: 0x0
				either (length? w/text) > 0[
						new_size/y: to-integer (h/text: (((img/size/y) * (to-integer w/text)) / (img/size/x)))
						new_size/x: (to-integer w/text)
						show h
					][
						new_size/x: to-integer (w/text: (((img/size/x) * (to-integer h/text)) / (img/size/y)))
						new_size/y: (to-integer h/text)
						show w
				]
				img_sm: to-image layout [origin 0x0 image img new_size]
				img_name: copy/part img_name find img_name "."
				img_name: rejoin[img_name "_sm." format/text]
				either format/text = "png" [save/png to-file img_name img_sm]
					[save/bmp to-file img_name img_sm]
				;thumb/image: img_sm
				;show thumb
			][print rejoin["Error converting " "'" img_name "'"]]
		]
		clear images/lines: head images/lines
		insert images/lines read %.
		show images
	]
	at 160x86 format: choice "png" "bmp"
	at 160x116 text 120x120 "You can select multiple images by holding down the Ctrl key."
	;at 160x90 thumb: image %a.bmp 110x110
]